10 REM the Wonderful World of Eamon
20 REM
30 REM a computerized fantasy role-playing system origionaly made for
40 REM the apple computer system by Donald Brown,407 Peery Parkway
50 REM Golden, CO 80401
60 REM
70 REM Programmed for MBASIC by Jon Walker,Video Shop,139 S. Central
80 REM Marshfield, WI 54449
90 REM
100 REM ///Boot up program for Eamon system.
110 REM ///Gets name of player and send to main hall or new players
120 REM
130 CLS
135 FOR I=1 TO 24:PRINT:NEXT I
140 PRINT,"**************************************"
150 PRINT,"*                                    *"
160 PRINT,"*    THE WONDERFUL WORLD OF EAMON    *"
165 PRINT,"*            VERSION 1.1             *"
170 PRINT,"*                                    *"
180 PRINT,"*     Origional work by Donald       *"
190 PRINT,"*                       Brown        *"
200 PRINT,"*                                    *"
210 PRINT,"*     Converted  by Jon              *"
220 PRINT,"*                   Walker           *"
230 PRINT,"*                                    *"
240 PRINT,"**************************************"
250 PRINT
251 A$=INKEY$:IF A$=CHR$(27) THEN 280
255 GOSUB 3000
261 PRINT,"**************************************"
262 PRINT,"*                                    *"
263 PRINT,"*    NON COMERCIAL DISTRIBUTION IS   *"
264 PRINT,"*              WELCOME               *"
265 PRINT,"*                                    *"
266 PRINT,"**************************************"
267 PRINT
268 GOSUB 3000
270 REM
280 CLS
290 X=RND(10)
300 OPEN"R",#1,"CHARACTE.RS",255
310 FIELD 1,255 AS B$
320 GET#1,1
330 NC=VAL(B$)
340 PRINT"     You are in the outer chamber of the hall of the guild of"
350 PRINT"free adventurers.  Many men and women are guzzling beer and"
360 PRINT"there is loud singing and laughter.  On the north side of the"
370 PRINT"chamber is a cubbyhole with a desk.  Over the desk is a sign"
380 PRINT"which says 'REGISTER HERE OR ELSE!'."
390 PRINT:PRINT:PRINT"Do you go over to the desk or join the men drinking the beer?"
400 PRINT"(hit 'D' for desk or 'M' for men)   ";
410 A$=INKEY$:IF A$="" THEN 410
420 IF A$="d" OR A$="D" THEN 500
430 IF A$<>"m" AND A$<>"M" THEN 410
440 PRINT A$:FOR I=1 TO 22:PRINT:NEXT I
450 PRINT"     As you go over to the men, you feel a sword being thrust"
460 PRINT"through your back and you hear someone say, 'You really must"
470 PRINT"learn to follow directions!'":END
480 REM
490 REM
500 PRINT A$:FOR I=1 TO 12:PRINT:NEXT I
510 PRINT"     You are greeted there by a burly Irishman who looks at you with a"
520 PRINT"scowl and asks you, 'What's your name?'"
530 PRINT:PRINT"You give him your name (type it now)    ";
540 INPUT TNAME$
550 PRINT:IF TNAME$<>"" THEN 600
560 PRINT"     He pulls out a sword and begins to sharpen it  saying,"
570 PRINT"'Beware the blud stains on the floor.  They belong to a poor"
580 PRINT"lad who came in last week and wonna give me his name.'"
590 PRINT:PRINT:GOTO 530
600 IF LEN(TNAME$)<=30 THEN 630
610 PRINT"    He scowls at you and says, 'Yer name's too long fer me book."
620 PRINT"I canna use more than thirty letters.'":PRINT:PRINT:GOTO 530
630 A1$="":FOR I=1 TO LEN(TNAME$)
631 A1$=A1$+ CHR$( ASC(MID$(TNAME$,I,1)) - ABS(MID$(TNAME$,I,1)>="a" AND MID$(TNAME$,I,1)<="z")*32)
632 NEXT I:T1$=TNAME$:TNAME$=A1$
635 PRINT"    He starts to look through his book, muttering to himself about"
670 PRINT"'Strange Saxon names'";
675 IF T1$<>TNAME$ THEN PRINT", and something about people who don't use caps lock." ELSE PRINT "."
700 PRINT
710 FOR R=1 TO NC:GET#1,R+1
720 IF LEFT$(B$,1)="," THEN 770
730    FOR I=1 TO LEN(B$)
740       IF MID$(B$,I,1)="," THEN 760
750    NEXT I:PRINT"SYSTEM ERROR, BAD FILE DATA":STOP
760    IF TNAME$= LEFT$(B$,I-1) THEN 880
770 NEXT R:PRINT"    He looks at you and says, 'Yer names na here.  Have ye given it to me"
790 PRINT"aright?'      How do you answer (Hit 'Y' or 'N' ) ";
800 A$=INKEY$:IF A$="" THEN 800
810 IF A$<>"n" AND A$<>"N" THEN 830
820 PRINT A$:PRINT:PRINT"     He says, 'Well try again!'":PRINT:GOTO 530
830 IF A$<>"y" AND A$<>"Y" THEN 800
840 PRINT A$:PRINT:PRINT"    He hits his forehead and says 'Ah, ye must be new here!"
850 PRINT"Well, wait just a minute and I'll bring someone out to take care of ye.'":PRINT
870 GOSUB 920 :RUN"NEWGUY"
880 PRINT:PRINT:PRINT"    He looks up and says, 'Ah, here ye be!  Well, go and have fun in the Hall!'":PRINT
900 GOSUB 920:RUN"MAINHALL"
910 STOP
920 OPEN "O",#2,"ADVENTUR.ER"
930 PRINT#2,TNAME$+","+STR$(R)
940 CLOSE #2
950 RETURN
3000 FOR I=1 TO 6:PRINT:NEXT I
3265 FOR I=1 TO 500:A$=INKEY$:IF A$=CHR$(27) THEN 3270
3266 NEXT I
3270 FOR I=1 TO 12:PRINT:NEXT I
3280 RETURN
